Image of a square under the logarithm

Here’s the image of a square of side length π under the logarithm:

toPoint[z_] = {Re[z],Im[z]};
logPic = ParametricPlot[toPoint[Log[x+I*y]],{x,0,Pi},{y,0,Pi},
Mesh -> True, BoundaryStyle->Thick]

To get a grip on this, let’s parametrize the boundary of the square and visualize how that boundary maps onto the parts above.

γ[t_] := (Piecewise[{{t, 0≤t<Pi}, {Pi+(t-Pi)*I, Pi≤t<2Pi}, {(3Pi-t)+Pi*I, 2Pi≤t<3Pi}, {(4Pi-t)*I, 3Pi≤t≤4Pi}}]);
squarePic = ParametricPlot[toPoint[x+I*y],{x,0,Pi},{y,0,Pi},
Mesh -> True, BoundaryStyle->Thick];
Manipulate[
Grid[{{
Show[squarePic, ImageSize -> {Automatic,200}, 
Epilog->{Green,PointSize[Large],Point[toPoint[γ[t]]]}],
Show[logPic, ImageSize -> {Automatic,200},
Epilog->{Red,PointSize[Large],Point[toPoint[Log[γ[t]]]]}]
}}, Spacings->4],
{t,0.01,4Pi-0.01}, SaveDefinitions->True]