Complex images of the elementary transcendental functions

The locators on the left determine a rectangle in the complex plane; the image of the rectangle under the selected function is shown on the right.  The locators snap to the grid allowing easy selection of natural domains for these functions.  Appropriate branches of the log, arcsin, and arccos map a range on the right to the corresponding domain on the left.

domainOptions = {Axes -> True,Frame -> True,
FrameTicks -> {{-2Pi,-Pi,Pi,2Pi},{-2Pi,-Pi,Pi,2Pi}},
PlotRange -> {{-7,7},{-7,7}}, ImageSize -> 300,
GridLines -> {Range[-2Pi,2Pi,Pi/2],Range[-2Pi,2Pi,Pi/2]},
GridLinesStyle -> Directive[Dashing[{0.02,0.01}],LightGray],
PlotStyle -> Thick
};
rangeOptions = {Axes -> True, Frame -> True,
PlotRange -> {{-7,7},{-7,7}}, ImageSize -> 300,
PlotStyle -> Thick};
dents = Flatten[Table[{x,y},{x,-2Pi,2Pi,Pi/2},
{y,-2Pi,2Pi,Pi/2}],1];
nf = Nearest[dents];
Manipulate[
If[Norm[p-First[nf[p]]]<0.2, p = First[nf[p]]];
If[Norm[q-First[nf[q]]]<0.2, q = First[nf[q]]];
Which[
p == q,
Row[{Graphics[Point[{p,q}], Most[domainOptions]],
Graphics[Point[{Re[f[p[[1]]+I*p[[2]]]],
Im[f[p[[1]]+I*p[[2]]]]}],Most[rangeOptions]]}],
p[[1]] == q[[1]],
Row[{
ParametricPlot[{p[[1]],y},{y,p[[2]],q[[2]]},
Evaluate[domainOptions]],
ParametricPlot[{Re[f[p[[1]]+I*y]],Im[f[p[[1]]+I*y]]},
{y,p[[2]],q[[2]]}, Evaluate[rangeOptions]]}],
p[[2]] == q[[2]],
Row[{
ParametricPlot[{x,p[[2]]},{x,p[[1]],q[[1]]},
Evaluate[domainOptions]],
ParametricPlot[{Re[f[x+I*p[[2]]]],Im[f[x+I*p[[2]]]]},
{x,p[[1]],q[[1]]}, Evaluate[rangeOptions]]}],
True,
Row[{
ParametricPlot[{x,y},{x,p[[1]],q[[1]]},{y,p[[2]],q[[2]]},
Evaluate[domainOptions]],
ParametricPlot[{Re[f[x+I*y]],Im[f[x+I*y]]},
{x,p[[1]],q[[1]]},{y,p[[2]],q[[2]]},
Evaluate[rangeOptions]]}]],
{{f,Exp,"function"},{Exp,Sin,Cos}},
{{p,{-Pi/2,-Pi}},{-7,-7},{7,7},Locator},
{{q,{Pi/2,Pi}},{-7,-7},{7,7},Locator},
SaveDefinitions -> True]

Recall that (e^z)=(e^x)(cos(y)+i sin(y)), where z=x+i y.  It follows that a vertical line (determined by a fixed x) maps to a circle and a horizontal line (determined by a fixed y) maps to a ray emanting from the origin.

Also, sin(z)=sin(x)cosh(y)+i cos(x)sinh(y).  It follows that the half-strip {z∈ℂ:0≤Re(z)≤π/2, 0≤y} maps onto the first quadrant.

Incidentally, we can find these types of expansions using Mathematica's ComplexExpand function.

ComplexExpand[Sin[x+I*y]]